[cunster]

Pro Rechnung(also pro Zeile) gibt es eine neue Herstellernummer.
Davon die Anzahl soll am Ende ausgespuckt werden.
Sorry für meine Ungenauigkeit.

[tomcrswer]

Eine Beispieldatei würde wahrscheinlich helfen...

Du willst ein Tabellenblatt das so aussieht?

  |     A     |          B           |                 C                   |
--|-----------|----------------------|-------------------------------------|
1 | Kundennr. | Anzahl Herstellernr. | Rechnungsbetrag für diese Kundennr. |
2 |           |                      |                                     |

Dann wäre VBA nicht notwendig, wie ja auch eitch schon geschrieben hat.

[eitch100]

Also... angenommen deine Daten stehen in Tabelle1 (Beschriftung:Kundennummer Zelle A1, Rechnungsbetrag aktuell Zelle N1). Die Werte beginnen ab Zeile 2.

Auswertung ist dann auf Tabelle2 (Beschriftung: Kundennummer Zelle A1, Herstellungsnummer Zelle B1, Rechnungsbetrag Zelle C1)

Formeln in Tabelle2:
A2
=MIN(Tabelle1!A2:A1000)

A3 und herunterkopieren
=WENN(MAX(Tabelle1!A$2:A$1000)=MAX(A$2:A2);"";KGRÖSSTE(Tabelle1!A$2:A$1000;ZÄHLENWENN(Tabelle1!A$2:A$1000;">"&A2)))

B2 und herunterkopieren
=WENN(ISTZAHL(A2);ZÄHLENWENN(Tabelle1!A$2:A$1000;A2);"")

C2 und herunterkopieren
=WENN(ISTZAHL(A2);SUMMEWENN(Tabelle1!A$2:A$1000;A2;Tabelle1!N$2:N$1000);"")

Edit: So ginge es auch, weil die Formeln Text sowieso ignorieren. 
Aber man muss sich da sicher sein. Vorteil: die komplette Spalte wird berücksichtigt...
A2
=MIN(Tabelle1!A:A)

A3 und herunterkopieren
=WENN(MAX(Tabelle1!A:A)=MAX(A$2:A2);"";KGRÖSSTE(Tabelle1!A:A;ZÄHLENWENN(Tabelle1!A:A;">"&A2)))

B2 und herunterkopieren
=WENN(ISTZAHL(A2);ZÄHLENWENN(Tabelle1!A:A;A2);"")

C2 und herunterkopieren
=WENN(ISTZAHL(A2);SUMMEWENN(Tabelle1!A:A;A2;Tabelle1!N:N);"")

Die Kundennummer muss hierbei aber eine Zahl sein. Ist ausgelegt für Zeile 2 bis 1000. Für die Herstellungsnummer habe ich die Häufigkeit der Kundennummer genommen; sollte ja dasselbe ergeben.

P.S. als kleinen Test könntest du auf Tabelle2 noch irgendwo zwei Summen berechnen. Die sollten "günstigstenfalls" identisch sein...

alco z.B. in D2 
=SUMME(C:C)

D3
=SUMME(Tabelle1!N:N)